# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

EAPI="2"

inherit eutils flag-o-matic multilib

# weird version and paths stuff, for version bumps we normally only have
# to modify REV_DIR and REF_VER
REV_DIR="248"
#REF_VER="${PV}"
REF_VER="0.1.6"
S="${WORKDIR}/${PN}-${REF_VER}"

DESCRIPTION="Graphical LCD Driver"
HOMEPAGE="http://projects.vdr-developer.org/projects/show/graphlcd"
SRC_URI="http://projects.vdr-developer.org/attachments/download/${REV_DIR}/${PN}-${REF_VER}.tgz
	http://www.muresan.de/graphlcd/patches_lib/${P}_nostrip.diff.gz
	http://www.muresan.de/graphlcd/patches_lib/${P}_n800.diff.gz
	http://www.muresan.de/graphlcd/patches_lib/${P}_gu256x64-355-wiring.diff.gz
	http://www.muresan.de/graphlcd/patches_lib/${PN}-0.1.5_utf8_v2.diff.gz
	http://www.muresan.de/graphlcd/patches_lib/${P}_valgrind_v2.diff.gz"

KEYWORDS="amd64 x86 ~ppc"
SLOT="0"
LICENSE="GPL-2"
IUSE="debug truetype g15"

DEPEND=""

RDEPEND="truetype? ( media-libs/freetype media-fonts/corefonts )
	g15? ( app-misc/g15daemon )"

src_prepare() {
	sed -i Make.config -e "s:usr\/local:usr:" -e "s:FLAGS *=:FLAGS ?=:"
	sed -i Makefile -e "s:${REF_VER}:${PV}:"
	use !truetype && sed -i "s:HAVE_FREETYPE2:#HAVE_FREETYPE2:" Make.config
	use truetype && sed -i "s:#HAVE_FREETYPE2:HAVE_FREETYPE2:" Make.config
	epatch "${WORKDIR}/${P}_nostrip.diff"
	epatch "${WORKDIR}/${P}_n800.diff"
	epatch "${WORKDIR}/${P}_gu256x64-355-wiring.diff"
	epatch "${WORKDIR}/${PN}-0.1.5_utf8_v2.diff"
	epatch "${WORKDIR}/${P}_valgrind_v2.diff"
}

src_compile() {
	if use debug; then
		filter-flags -O2 -O1
		append-flags -g -ggdb -O0
		filter-ldflags -O2 -O1
		append-ldflags -ggdb -O0
	fi
	emake || die "emake failed"
}

src_install() {
	make STRIP="" DESTDIR="${D}"/usr LIBDIR="${D}"/usr/$(get_libdir) install || die "make install failed"

	insinto /etc
	doins graphlcd.conf

	dodoc docs/* HISTORY README
}